13 229S ...      SEG      TPOBJ,867,SECT.FILE,,G505
   8 22FL    #OPT  K0TPOBJ=K0OLP 
   8 22_=    #OPT  K6TPOBJ=K6OLP 
   7 23DW    #LIS  K0TPOBJ   
   4 23JR ...[   
  15 23NN ...[ (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982
  13 23SK ...[     THIS EXCLUDES CODE UNDER #SKI G505
   4 23YG ...[   
   7 244C ...#OPT G505 = 0   
   6 248# ...#SKI G505&1 
  17 24#9 ...# WITH UGUG EDIT M505 (3-SHIFT WORKING FOR MOP ONLINE)  
  19 24D6    # THIS SEGMENT DOES AN OFFLINE TP PERI (TYPE 1 MODES 0,4,8 OR 16
  14 24XQ    #  COUNT 1-128)  ISSUED BY AN OBJECT PROGRAM
  11 25CB    #     AWORK1=N/CH IN ADATA/ACONV
  14 25X2    #           =#40000000 IF ENTRY FROM OFFREL 
  15 26BL    #     AWORK2=B0-5   LAST SHIFT IN ADATA/ACONV   
  17 26W=    #            B7=1   LAST CHARACTER OF PERI IS A DELTA.  
  14 27*W    #            B9=1   IMPLEMENTING *LP PERIS. 
  12 27KN    #            B18-23 BRANCH POINTER  
  17 27TG    #     AWORK3=2      ADATA/ALINE CONTAINS WHOLE RECORD   
  16 28*6    #           =1                /          2000 CHARS 
  14 28SQ    #     AWORK4=B18-23 FILE MODE (#4,#24,#12)  
  17 29S2    #            B0=1   END OF MULTIFILE HAS BEEN REACHED   
  13 2=3S    #            B1=1   FILE IS NEARLY FULL 
   4 2=?L    #   
  11 2?=W          SEGENTRY K1TPOBJ,Z1TPOBJ  
  11 2?K?          SEGENTRY K3TPOBJ,Z3TPOBJ  
  11 2?XN          SEGENTRY K2TPOBJ,Z2TPOBJ  
   4 2#=6    #   
  15 2#PQ    MODE           #20100400           [PERI MODES  
  17 2*9B    TABLE          #04010101           [FILE MODES & PTRS   
   9 2*P2                   #24010302
   9 2B8L                   #12030404
   9 2BN=                   #00000000
   6 2BTD ...#SKI G505&1 
  19 2C2L ...MASKID         #70000706           [ PERMANENT BITS OF IDENTIND 
  18 2C7W    MAX            +129                [1 GREATER THAN MAXIMUM  
   8 2CCN    MAX4           +323 
   9 2CMG    MASK1          #60077777
   9 2D76    XBLANK         #76207620
   8 2DLQ    XALPHA         #74  
   8 2F6B    XBETA          #75  
   5 2FL2    PLINK1  
   9 2G5L          PAIR     TPOBJ,1  
  20 2G7T    Z2TPOBJ                            [ENTRY FROM LPOBJ TO IMPLEMENT   
  17 2G=4          STOZ     AWORK1(2)           [MODE 4 *LP PERIS.   
   8 2G#?          LDN   0  #74  
  20 2GBG          DCH   0  AWORK2(2)           [SET ALPHA SHIFT FOR BEGINNING.  
  10 2GDP          LDX   3  APETADDR(2)  
   8 2GGY          BRN      OKSH1
   5 2GK=    Z1TPOBJ 
   9 2H4W    #SKI  K6TPOBJ>799-799   
   9 2HJG          TRACE    FX2,TPOBJ
  17 2J46          LDCH  0  AWORK2(2)           [LAST SHIFT IN ADATA 
  14 2JHQ          BNZ   0  OKSH                [J IF OK 
   8 2K3B          LDN   0  #74  
  17 2KH2          DCH   0  AWORK2(2)           [ALPHA FOR BEGINNING 
  15 2L2L    OKSH  LDX   3  APETADDR(2)         [PTR TO APET 
   9 2LG=          LOCKCA   3,ACAP(2)
   5 2LQ4    OKSH1   
  19 2L_W          LDX   4  ACAP(2)             [ADDRESS OF CA IN OBJ.PROG   
  18 2MFG          LDN   5  ACA1(2)             [ADDRESS OF CA IN AOLPT  
   7 2M_6          LDN   6  4
  16 2NDQ          FOUTMOVE 3,4,5,6,HLOCK1      [MOVE CA TO OLPA 
   8 2NG3          LDX   0  BIT9 
   9 2NH#          ANDX  0  AWORK2(2)
  20 2NJK          BZE   0  NOTLP               [J IF NOT IMPLEMENTING *LP PERIS.
   9 2NKW          LDEX  4  ACA1(2)  
   7 2NM7          LDX   0  4
   7 2NND          SBN   0  4
  15 2NPP          BZE   0  YM4                 [J IF MODE 4.
   9 2NR2          ACROSS   LPOBJ,2  
   4 2NS?    YM4 
  21 2NTJ          SBS   4  ACA1(2)             [SET MODE =0 IN AOLPT CONTROL AREA.  
   5 2NWT    NOTLP   
  17 2NYB          STOZ     ACA2(2)             [ZEROISE REPLY WORD  
   8 2TWT          PMODES   4,3  
   8 2T_4          ANDN  4  #10  
  18 2W3?          BNZ   4  NOTPACT             [J IF NOT COMPACT MODE   
   9 2W5G          LDX   4  MASK1(1) 
   9 2W7P          ANDS  4  ACA4(2)  
   5 2W9Y    NOTPACT 
   9 2W=3          LDX   0  AWORK4(2)
  18 2W=6          BNG   0  OUTF2               [J IF END OF MULTIFILE   
   8 2W=9          LDCT  0  #200 
   9 2W=#          ANDX  0  AWORK4(2)
  19 2W=C          BZE   0  NONEAR              [J IF FILE IS NOT NEARLY FULL
   8 2W=G          LDCT  0  #400 
  18 2W=K          BXE   0  AWORK1(2),NONEAR    [J IF ENTRY FROM OFFREL  
   8 2W=N        LDX   0  BIT9   
   9 2W=R          ANDX  0  AWORK2(2)
  21 2W=W          BZE   0  YFULL               [TAKE FILEFULL ACTION IF NOT *LP PERI
   9 2W=_          LDX   1  ACA4(2)  
   7 2W?4          BCHX  1  /
   7 2W?7          SBN   1  1
  15 2W?=          FADDRESS 3,1,HLOCK2          [X1 ->  PFCC 
   8 2W?*          LDN   0  #17  
   8 2W?D          ANDX  0  0(1) 
   8 2W?H          LDX   1  FX1  
   8 2W?L          ERN   0  #11  
  20 2W?P          BNZ   0  NONEAR              [J IF NOT THROW TO HEAD OF FORM  
   5 2W?S    YFULL   
   9 2W?X          SETREP2  FILEFULL 
  19 2W#2          BRN      NEARLY              [SIMULATE FILEFULL CONDITIONS
   5 2W#5    NONEAR  
  14 2W#=          LDX   3  ACA3(2)             [COUNT   
   8 2WRW          BZE   3  WC   
   8 2WXR          LDX   0  BIT9 
   9 2X3N          ANDX  0  AWORK2(2)
  16 2X7K          BNZ   0  YLPERI              [J IF *LP PERI   
   6 2X7R ...#SKI G505&1 
   4 2X7_ ...(   
   9 2X87 ...      LDX   0  MASKID(1)
  10 2X8* ...      ANDS  0  IDENTIND(2)  
   4 2X8H ...)   
   6 2X8P ...#SKI G505&1 
   4 2X8X ...(   
   8 2X95 ...      LDN   0  #10  
   9 2X9? ...      ANDX  0  ACA1(2)  
  15 2X9F ...      IF       0,ZE                [ SHIFT PERI 
   8 2X9M ...         LDN   6  6 
  11 2X9T ...         ANDX  6  IDENTIND(2)   
  16 2X=3 ...      AND      6,NZ                [ SHIFT DEVICE   
   6 2X=9 ...      THEN  
   8 2X=C ...         SLL   6  12
  11 2X=K ...         ORS   6  IDENTIND(2)   
   5 2X=R ...      FI
   4 2X=_ ...)   
  18 2X?G          BXGE  3  MAX(1),WC           [CHECK COUNT 0<COUNT<129 
   5 2XDN    YLPERI  
  17 2XKW          BXGE  3  MAX4(1),WC             [CHECK 0<COUNT<323
  16 2XR6          LDX   4  ACA4(2)             [BUFFER ADDRESS  
   7 2Y=Q          SLC   4  2
   7 2YQB          ADX   3  4
   7 2_=2          ADN   3  3
   7 2_PL          SRL   3  2
  16 329=          SRL   4  2                   [X4=BUFFER ADDRES
  16 32NW          SBX   3  4                   [X3=BUFFER LENGTH
  15 338G          CHECKA   4,3,RESV,APETADDR(2),,Q6,HLOCK2  
  13 33N6    Q6    LDEX  5  ACA1(2)             [MODE
   9 347Q    Q7    LDCH  6  MODE(1)  
  16 34MB          BXE   5  6,OKPM              [PERI MODE IS OK 
   7 3572          BCHX  1  /
   8 35LL          BNZ   6  Q7   
  18 366=          BRN      MOLE                [J.IF MODE NOT RECOGNISED
   4 36KW    OKPM
   8 375G    OKAL  SBX   1  FX1  
   8 37K6          LDX   3  FX1  
  15 384Q          LDX   6  FSCTM(2)            [FILE MODE   
   8 38JB          ANDN  6  #10  
  13 3942          LDEX  0  FSCTM(2)            [MODE
  15 39HL          BNZ   6  STOFM               [J IF GRAPHIC
  17 3=3=          ERN   0  6                   [CHANGE TO PREVIOUS  
  16 3=GW    STOFM DEX   0  AWORK4(2)           [STORE FILE MODE 
  17 3?2G    NEXMD LDCH  6  TABLE(3)            [NEXT MODE FROM TABLE
   8 3?G6          BNZ   6  OKFM 
  10 3?_Q          GEOERR   1,FILEMODE   
  16 3#FB    OKFM  BXE   6  0,MODOK             [FILE MODE IS OK 
   7 3#_2          ADN   3  1
  17 3*DL          BRN      NEXMD               [J TO TEST NEXT MODE 
   7 3*Y=    MODOK ADX   3  1
  17 3BCW          BZE   1  Q8                  [J IF PUNCH BLANKS   
  15 3BXG          LDCH  0  TABLE(3)            [BRANCH PTR  
  15 3CC6          DEX   0  AWORK2(2)           [STORE PTR   
  14 3CWQ    Q8    LDX   0  ALIMEY(2)           [LIMIT   
   4 3DBB    #SKI
  16 3DW2          BNG   0  Q9                  [J IF NOTLIMIT   
  19 3F*L          BXL   0  ACOUNT(2),OUTL      [J IF OUTPUT LIMIT EXCEEDED  
   8 3FT=    Q9    LDX   1  FX1  
  10 3G#W          HUNT     3,ADATA,ACONV
  16 3GSG          BPZ   3  PRESB               [J IF BLOCK EXIST
  18 3H#6          SETNCORE 35,3,ADATA,ACONV    [SET UP THE BUFFER BLOCK 
  20 3HRQ          STOZ     A1+1(3)             [INITIALIZE 2ND WORD OF RED TAPE 
  13 3J?B    PRESB LDX   6  ACA3(2)             [N/CH
   8 3JR2          SBN   5  #20  
  15 3K=L          BNZ   5  NOBL                [J IF NOT #20
  14 3KQ=          SLL   6  1                   [N/CH.2  
  17 3L9W    NOBL  STO   6  AWORK1(2)           [N/CH IN ADATA/ACONV 
   8 3LPG          ADN   6  15   
  13 3M96          SRL   6  2                   [N/W 
  17 3MNQ          BXL   6  ALOGLEN(3),NOCHL    [TEST BLOCK LENGTH   
   8 3N8B          ALTLEN   3,6  
  10 3NN2          HUNT     3,ADATA,ACONV
  19 3P7L    NOCHL LDX   7  3                   [REMEMBER PTR TO ADATA/ACONV 
  17 3PM=          LDX   6  AWORK1(2)           [N/CH IN ADATA/ACONV 
  15 3Q6W          ADN   3  A1+2                [BUFFER PTR  
  16 3QLG          WHICHMOP NOMOP               [J IF NOT MOP/MF 
   7 3R66          LDN   0  2
  18 3RKQ          STO   0  AWORK3(2)           [TRANSFER WHOLE RECORD   
  16 3S5B          BNZ   5  OUTMV                [J IF NOT #20   
   8 3SK2          BRN      ROUTS
  15 3T4L    NOMOP BNZ   5  OUTMV               [J IF NOT #20
  15 3TJ=          LDEX  0  AWORK4(2)           [FILE MODE   
   8 3W3W          SBN   0  #24  
  15 3WHG          BZE   0  ROUTS               [J IF BLANKS 
   9 3X36          STOZ     AWORK1(2)
  16 3XGQ          BRN      REPWD               [SET REPLY WORD  
  15 3Y2B    ROUTS SBN   6  1                   [ROUND DOWN  
  15 3YG2          SRL   6  2                   [N/W TO MOVE 
  15 3Y_L          LDX   0  XBLANK(1)           [_ _ =BLANKS 
   8 3_F=          STO   0  0(3) 
   7 3_YW          LDX   4  3
   7 42DG          ADN   4  1
  16 42Y6          BZE   6  ONEWD               [NO CHARS TO MOVE
   7 43CQ          SMO      6
  19 43XB          MOVE  3  0                   [MOVE BLANKS TO ADATA/ACONV  
  16 44C2    ONEWD LDX   6  AWORK1(2)           [N/CH IN ACONV   
   9 44WL          LDCH  5  AWORK2(2)
   8 45B=          BRN      STOZ 
  16 45TW    OUTMV LDX   5  3                   [PTR TO BUFFER   
  10 46*G          LDX   3  APETADDR(2)  
   9 46T6          LDX   4  ACA4(2)  
   8 46WC          LDX   0  BIT9 
   9 46XN          ANDX  0  AWORK2(2)
  17 46Y_          BZE   0  NOLP                [J IF NOT *LP PERI   
   7 472=          LDN   0  1
  19 473H          SBS   0  ACA3(2)             [REMOVE PFCC FROM COUNT OF   
  18 474S          SBS   0  AWORK1(2)           [CHARACTERS IN THIS PERI.
   7 4765          SBN   5  1
   7 477B          BCHX  5  /
   7 478M          BCHX  5  /
   7 479Y          BCHX  5  /
   4 47?9    NOLP
  18 47#Q          FOUTMVCH 3,4,5,6,HLOCK2      [MOVE OUT OF OBJ PROGRAM 
   8 47DM          LDX   0  BIT9 
   9 47JJ          ANDX  0  AWORK2(2)
  19 47NF          BNZ   0  NODEL               [IGNORE PREVIOUS PERI IF *LP 
   8 47SB        LDEX  0  ACA1(2)
   8 48#2          ANDN  0  #10  
  19 48RL          BNZ   0  NODEL               [J IF PERI MODE IS GRAPHIC.  
  21 49?=          LDCT  0  #002                [TEST IF BIT SET IN AWORK2 INDICATING
  21 49QW          ANDX  0  AWORK2(2)           ['LAST CH. OF PREVIOUS PERI WAS A DEL
  21 4==G          ERS   0  AWORK2(2)           [AND IF SO CLEAR BIT IN AWORK2 AND SE
  21 4=Q6          SMO      7                   [IN 2ND WORD OF RED TAPE IN ACONV.   
   8 4?9Q          ORS   0  A1+1 
   7 4?PB          LDX   3  7
   8 4#92          ADN   3  A1+2 
   7 4#NL          SBN   6  1
   7 4*8=          SRC   6  2
   7 4*MW          ADX   3  6
  21 4B7G          LDCH  0  0(3)                [TEST IF LAST CH OF THIS PERI IS A DE
   8 4BM6          SBN   0  #76  
  15 4C6Q          BNZ   0  NODEL               [J IF NOT.   
   8 4CLB          LDCT  0  #002 
   9 4D62          ORS   0  AWORK2(2)
   5 4DKL    NODEL   
   8 4F5=          WHICHMOP TPERI
   8 4FJW          BRN      ONEWD
  15 4G4G    TPERI LDEX  5  AWORK2(2)           [BRANCH PTR  
   9 4GJ6          ADN   5  PTR(1)   
   8 4H3Q    PTR   BRN      (5)  
  15 4HHB          BRN      STOMD               [CONVERSION  
  20 4J32          BRN      TSHIF               [CONVERSION IF TERM SHIFT=BETA   
  16 4JGL          BRN      NOCON               [NO CONVERSION   
  16 4K2=          BRN      STOMD               [SHIFT-GRAPHIC   
   4 4KFW    #   
  15 4K_G    TSHIF LDCH  0  AWORK2(2)           [LAST SHIFT  
   8 4LF6          SBN   0  #75  
  15 4LYQ          BNZ   0  NOCON               [J IF ALPHA  
  15 4MDB    STOMD LDCH  0  AWORK2(2)           [LAST SHIFT  
   7 4MY2          SLL   0  6
   7 4NCL          LDN   5  3
   9 4NX=          ANDX  5  ACA3(2)  
   7 4PBW          SRC   5  2
   7 4PWG          ORX   5  0
  19 4QB6          LDX   3  7                   [RESTORE PTR TO ADATA/ACONV  
  19 4QPT          LDCT   0  #002               [PRESERVE STATE OF DELTA BIT.
  18 4R5J          ADN   0  #77                 [AND PFCC FOR *LP PERIS. 
   9 4RF?          ANDS  0  A1+1(3)  
  16 4RT2          ORS   5  A1+1(3)             [UPDATE RED TAPE 
   9 4S#L          LDX   0  ACA3(2)  
   8 4SS=          ADN   0  11   
   7 4T?W          SRL   0  2
  16 4TRG          STO   0  A1(3)               [N/W IN RECORD   
  15 4W?6    NEWCN LDEX  6  ACA1(2)             [PERI MODE   
   7 4WQQ          LDX   0  6
   8 4X=B          ANDN  0  #10  
  15 4XQ2          BNZ   0  MODGR               [J IF GRAPHIC
  14 4Y9L          ORN   6  #20                 [ALLCHARS
  15 4YP=    MODGR LDEX  7  AWORK4(2)           [FILE MODE   
   8 4_8W          TRANSFOR 6,7  
   9 4_NG          TESTRPN2 STOP,REST
   7 5286          LDN   0  2
  19 52MQ          STO   0  AWORK3(2)           [ALINE CONTAINS WHOLE RECORD 
   4 537B    REST
  10 53M2          HUNT     3,ADATA,ACONV
  15 546L          LDX   7  3                   [REMEMBER PTR
  16 54L=          LDX   0  A1(3)               [N/W IN NEW RCD  
  15 555W          SBN   0  2                   [-RED TAPE   
   7 55KG          SLL   0  2
   9 5656          LDCH  4  A1+1(3)  
  17 56JQ          SRL   4  4                   [N/CH IN LAST WORD   
   8 574B          BZE   4  OKCH 
   7 57J2          SBN   0  4
   7 583L          ADX   0  4
  19 58H=    OKCH  STO   0  AWORK1(2)           [UPDATE N/CH IN ADATA/ACONV  
  18 592W          BNZ   0  NOCON               [J IF ACONV IS NOT EMPTY 
   9 59GG          LDX   0  AWORK3(2)
  14 5=26          LDN   6  0                   [N/CH=0  
   8 5=FQ          BZE   0  REPWD
   9 5=_B          LDCH  5  AWORK2(2)
   8 5?F2          BRN      SEARC
   9 5?YL    NOCON LDX   0  ACA1(2)  
  15 5#D=          ORX   0  AWORK4(2)           [FILE MODE   
   8 5#XW          ANDN  0  #10  
  15 5*CG          LDX   6  AWORK1(2)           [N/CH TO MOVE
  14 5*X6          BNZ   0  SHICH               [J IF #10
  15 5BBQ          LDX   3  7                   [PTR TO ACONV
  16 5BWB    TEST  LDX   4  AWORK1(2)           [N/CH IN ACONV   
   8 5BY_          LDX   0  BIT9 
   9 5C3J          ANDX  0  AWORK2(2)
  15 5C67          BZE   0  NOLP4               [LP PERI ?   
  18 5C8Q          BZE   4  SHICH                   [CHECK FOR 0 TX LEN  
   5 5C?*    NOLP4   
   9 5CB2          LDCH  5  AWORK2(2)
  10 5CC5          HUNT     2,ADATA,ALINE
   8 5CD8          BPZ   2  NOLP7
   7 5CF?          SBX   2  2
   8 5CGB          BRN      NOLP5
   5 5CHF    NOLP7   
   8 5CJJ          LDX   2  A1(2)
   7 5CKM    NOLP5 LDX   0  4
   7 5CLQ          ADX   2  6
   8 5CMT          SBN   2  2009 
   8 5CNY          BNG   2  NOLP6
   7 5CQ3          SBX   0  2
   7 5CR6          SBN   0  1
   7 5CS9    NOLP6 LDX   2  0
  21 5CTL          LDCT  0  #002              [TEST IF BIT SET IN ACONV INDICATING   
  21 5D*=          ANDX  0  A1+1(3)             ['LAST CH OF PREVIOUS PERI WAS A DELT
   9 5DSW          ERS   0  A1+1(3)  
  19 5F#G          BNZ   0  TAST                [IF SO CLEAR BIT AND JUMP.   
  17 5FS6    TCHAR LDCH  0  A1+2(3)             [LOAD NEXT CHARACTER 
  15 5G?Q          BXE   0  XALPHA(1),STORE     [J IF ALPHA  
  15 5GRB          BXE   0  XBETA(1),STORE      [J IF BETA   
   8 5H?2          SBN   0  #76  
  16 5HQL          BNZ   0  NOSH                [J IF NO SHIFT   
   7 5J==          BCHX  3  /
   7 5JG4          SBN   2  1
   8 5JPW          BCT   4  TAST 
  17 5K9G          BRN      STOZ                [J IF NO MORE CHARS  
  16 5KP6    TAST  LDCH  0  A1+2(3)             [LOAD SUCCESSOR  
   8 5L8Q          SBN   0  #32  
  15 5LNB          BNZ   0  NOSH                [J IF NOT N/L
   8 5LQ#          LDX   2  FX2  
   8 5LS?          LDX   0  BIT9 
   9 5LY8          ANDX  0  AWORK2(2)
  18 5M45          BNZ   0  WRONGLPCH           [ILLEGAL CH IF *LP PERI  
   7 5M82          LDN   0  2
  15 5MML          STO   0  AWORK3(2)           [SET SWITCH  
   7 5N7=          SLC   3  2
   7 5NLW          ADN   3  1
  15 5P6G          LDX   0  7                   [PTR TO ACONV
   7 5PL6          SLC   0  2
  16 5Q5Q          SBX   3  0                   [N/CH UP TO N/L  
  17 5QKB          SBS   3  AWORK1(2)           [UPDATE N/CH IN ACONV
  13 5R52          SBN   3  2                   [-N/L
   7 5RJL          LDX   6  3
   8 5S4=          BRN      SEARC
   5 5SHW    SHICH   
   8 5T3G          LDN   5  #74  
   8 5TH6          BRN      STOZ 
   5 5W2Q    STORE   
   8 5W=J          BZE   2  NOSH 
   8 5WGB          BNG   2  NOSH 
   7 5WQ8          LDX   5  0
   7 5X22    NOSH  BCHX  3  /
   7 5X9S          SBN   2  1
  17 5XFL          BCT   4  TCHAR               [J TO TEST NEXT CHAR 
   8 5XMF    STOZ  LDX   2  FX2  
   9 5XT#          STOZ     AWORK1(2)
   5 5Y38    SEARC   
   8 5Y56          LDX   0  BIT9 
   9 5Y74          ANDX  0  AWORK2(2)
  17 5Y92          BZE   0  NLP                 [J IF NOT *LP PERI   
   7 5Y=Y          LDX   3  7
  21 5Y#W          NAME     3,ADATA,ALINE       [RENAME ACONV AN ALINE FOR OUTPUT.   
  20 5YBS          ADN   6  8                   [UPDATE TWO WORDS OF RED TAPE.   
  18 5YDQ          STO   6  A1(3)               [RECORD HEADER IN CHARS. 
   9 5YGN          LDCH  0  AWORK2(2)
   7 5YJL          SLL   0  6
  19 5YLJ          ORS   0  A1+1(3)             [LAST SHIFT OF PREVIOUS PERI.
  19 5YNG          DCH   5  AWORK2(2)           [TERMINAL SHIFT OF THIS PERI.
   8 5YQD          BRN      SETRT
   4 5YSB    NLP 
  10 5YW#          HUNT     3,ADATA,ALINE
  16 5YYG          BPZ   3  OKBL                [J IF ALINE EXIST
  11 5_D6          SETNCORE 35,3,ADATA,ALINE 
  10 5_XQ          HUNT     1,ADATA,ACONV
  18 62CB          LDX   7  1                   [REMEMBER PTR TO ACONV   
  16 62X2          LDN   0  8                   [N/CH IN ALINE   
   8 63BL          STO   0  A1(3)
   9 63W=          LDCH  0  AWORK2(2)
   7 6464          SLL   0  6
   8 64*W          ORN   0  #41  
  19 64KN          STO   0  A1+1(3)             [TERMINAL SHIFT PLUS PFCC.   
   4 64TG    OKBL
   9 65*6          DCH   5  AWORK2(2)
   8 65SQ          LDX   4  A1(3)
  16 66#B          ADX   4  6                   [+N/CH FROM ACONV
   7 66S2          LDX   1  4
   7 67?L          ADN   4  3
   7 67R=          SRL   4  2
  16 68=W          LDX   0  ALOGLEN(3)          [LENGTH OF ALINE 
  14 68QG          BXGE  0  4,OKLEN             [J IF OK 
   8 69=6          SBN   4  503  
   8 69PQ          BNG   4  OKEX 
   8 6=9B          SBN   1  2008 
  17 6=P2          SBX   6  1                   [UPDATE N/CH TO MOVE 
  17 6?8L          ADS   1  AWORK1(2)           [UPDATE N/CH IN ACONV
  14 6?N=          LDX   0  AWORK3(2)           [SWITCH  
  17 6#7W          ADS   0  AWORK1(2)           [ADD 2 CHARS FOR N/L 
   7 6#MG          LDN   0  1
  20 6*76          STO   0  AWORK3(2)           [SWITCH FOR TRANSFER INTO FURB   
   7 6*LQ          NGN   4  1
  16 6B6B    OKEX  ADN   4  503                 [X4=NEW LENGTH   
  18 6BL2          ALTLEN   3,4                 [CHANGE ALINE'S LENGTH   
  10 6C5L          HUNT     3,ADATA,ACONV
  15 6CK=          LDX   7  3                   [REMEMBER PTR
  10 6D4W          HUNT     3,ADATA,ALINE
  16 6DJG    OKLEN LDX   5  A1(3)               [N/CH IN ALINE   
   7 6F46          SRC   5  2
   7 6FHQ          ADX   5  3
  15 6G3B          ADN   5  A1                  [PTR FOR MOVE
  15 6GH2          LDX   4  7                   [PTR TO ACONV
   8 6H2L          ADN   4  A1+2 
   8 6HG=          BZE   6  NOTMV
  20 6H_W          BNG   6  NOMV                [IE NEWLINE SPLIT OVER TWO PERIS.
   7 6JFG          SMO      6
  17 6J_6          MVCH  4  0                   [MOVE RECORD TO ALINE
   4 6KDQ    NOMV
  17 6KYB          ADS   6  A1(3)               [UPDATE N/CH IN ALINE
  16 6LD2    NOTMV LDX   5  AWORK1(2)           [N/CH IN ACONV   
   8 6LXL          BZE   5  NEMPT
  17 6MC=          LDX   0  4                   [PTR TO NEW RECORD   
  14 6MWW          LDX   1  AWORK3(2)           [SWITCH  
  15 6NBG          BZE   1  NLNOT               [J IF NO N/L 
  12 6NW6          SBN   1  1                   [
  20 6P*Q          BZE   1  NLNOT               [J IF RECORD CONTAINS 2000 CHARS 
   7 6PTB          BCHX  0  /
  20 6Q*2          BNG   6  NLNOT               [J IF NEWLINE SPLIT OVER 2 PERIS.
  15 6QSL          BCHX  0  /                   [IGNORE N/L  
  15 6R#=    NLNOT LDX   1  7                   [PTR TO ACONV
   8 6RRW          ADN   1  A1+2 
   7 6S?G          SMO      5
  17 6SR6          MVCH  0  0                   [MOVE RECORD BACKWARD
  16 6T=Q    NEMPT LDX   0  A1(3)               [N/CH IN ALINE   
   8 6TQB          SBN   0  2008 
  18 6W=2          BZE   0  SETRT               [J IF RECORD=2000 CHARS  
  16 6WPL          LDX   0  AWORK3(2)           [SWITCH FOR N/L  
   8 6X9=          BZE   0  REPWD
   8 6XNW    SETRT LDX   1  A1(3)
   7 6Y8G          SRC   1  2
   8 6YN6          LDCT  0  #600 
   7 6_7Q          ANDX  0  1
  15 6_MB          LDEX  4  AWORK4(2)           [FILE MODE   
   8 7272          SBN   4  #12  
  16 72JB          BNZ   4  NGRAPH              [J IF NOT GRAPHIC
   8 72_Q          ORN   0  #41  
   8 73C6          BRN      TARGR
   5 73SG    NGRAPH  
  16 749W          ORX   0  A1+1(3)           [PFCC +LAST SHIFT. 
   5 74M=    TARGR   
  16 754Q          STO   0  A1+1(3)             [SET 2ND WORD RT 
   8 75JB          NGX   0  A1(3)
  19 7642          ANDN  0  3                   [N/CH TO SPACEFILL LAST WORD 
  18 76HL          BZE   0  NOSPA               [J IF LAST WORD IS FULL  
  14 773=          LDN   4  #20                 [SPACE   
   7 77GW    STOR  SMO      3
  15 782G          DCH   4  A1(1)               [INSERT SPACE
   7 78G6          BCHX  1  /
   8 78_Q          BCT   0  STOR 
   5 7933    NOSPA   
  15 794#          LDX   0  BIT9                [LP PERI ?   
   9 795K          ANDX  0  AWORK2(2)
   9 796W          BZE   0  NOTRUC   
   7 7987          ADX   1  3
   5 799D    SPACES  
  17 79=P          SBN   1  1                     [ELIMINATE SPACES  
   8 79#2          LDX   4  A1(1)
   9 79*?          SPACECT 4,2,SPACES
  19 79BJ          SBX   1  3                    [X2 GIVES NO OF SPACES IN   
  15 79CT          ADN   1  1                    [LAST WORD  
  17 79F6          LDX   0  2                    [0 SP = 0 VALID CHAR
  18 79GC          SLC   2  1                     [1 SP =3 VALID CHARS   
  18 79HN          ADX   0  2                     [2 SP = 2 VALID CHARS  
  18 79J_          ANDN  0  3                     [3 SP = 1 VALID CHAR   
   7 79L=          SRC   0  2
  19 79MH          LDCT  2  #600                  [PUT NEW NO OF VALID CHARS 
   9 79NS          ORS   2  A1+1(3)  
  16 79Q5          ERS   2  A1+1(3)               [IN LAST WORD  
   9 79RB          ORS   0  A1+1(3)  
   8 79SM          LDX   2  FX2  
   5 79TY    NOTRUC  
  18 79X9          STO   1  A1(3)                  [NO OF WORDS IN RECORD
  16 79_2          WHICHMOP NOMF                [J IF NOT MOP/MF 
  10 7=DL          NAMETOP  3,FILE,FRB   
  20 7=Y=          LDX   5  AWORK1(2)           [NEGATIVE IF ENTRY FROM OFFREL   
   8 7?CW          ORX   5  FX2  
  18 7?XG          OUTMOP   OLPFL,K1TPOBJ       [OUTPUT RECORD TO MOP/MF 
   4 7#C6    NOMF
  18 7#WQ          LDX   4  1                   [REMEMBER RECORD LENGTH  
  15 7*BB          LDX   5  3                   [PTR TO ALINE
   8 7*W2          LDCT  0  #400 
  11 7B*L          BXU   0  AWORK1(2),STEP   
  17 7BT=          STEP     ,0(1),FORCED        [ENTRY FROM OLPODD   
   8 7C#W          BRN      TESTR
   4 7CSG    STEP
  10 7D#6          STEP     ,0(1),ANSWER 
   5 7DRQ    TESTR   
  21 7F?B          TESTREP2 APPWAIT,WAIT,FNEARLY,SETSW,COORED,SADAT,GLUTTON,TOOMUCH,-
  10 7FR2                   FILEFULL,WAIT
   7 7G=L    TREP  LDX   2  5
   8 7GQ=          BRN      RMOVE
   8 7H9W    NOAPP LDCT  0  #400 
  17 7HPG          BXE   0  AWORK1(2),UP        [J IF LAST TRANSFER  
  17 7J96          BRN      OUTF                [OUTPUT 'FILE FULL'  
   8 7JNQ    SETSW LDCT  0  #200 
  15 7K8B          ORS   0  AWORK4(2)           [SET SWITCH  
  10 7L7L    SADAT HUNT     2,ADATA,ALINE
   8 7LM=    RMOVE ADN   2  A1   
  17 7M6W          SMO      4                   [MOVE RECORD TO FUWB 
   7 7MLG          MOVE  2  0
   7 7N66          LDX   3  2
   8 7NKQ          LDX   2  FX2  
   8 7NMN          LDX   0  BIT9 
   9 7NPL          ANDX  0  AWORK2(2)
  17 7NRJ          BZE   0  NOFREE              [J IF NOT *LP PERI.  
   8 7NTG          SBN   3  A1   
  15 7NXD          FREECORE 3                   [FREE ALINE  
   8 7N_B          BRN      REPWD
   5 7P3#    NOFREE  
   7 7P5B          LDN   0  8
  16 7PK2          STO   0  0(3)                [N/CH IN ALINE   
  16 7Q4L          LDCH  0  AWORK2(2)           [TERMINAL SHIFT  
   7 7Q9S          SLL   0  6
   8 7QC2          ORN   0  #41  
   8 7QJ=          STO   0  1(3) 
  16 7R3W    OLPFL LDX   6  AWORK1(2)           [N/CH IN ACONV   
   8 7RHG          LDCT  0  #400 
  17 7S36          BXE   0  AWORK1(2),UP        [J IF LAST TRANSFER  
  15 7SGQ          STOZ     AWORK3(2)           [UNSET SWITCH
  17 7T2B          BZE   6  NOMOR               [NO CHARS IN ACONV   
  10 7TG2          HUNT     3,ADATA,ACONV
   7 7T_L          LDX   7  3
  17 7WF=          BRN      NOCON                [MORE CHARS IN ACONV
  10 7WYW    NOMOR MHUNT    3,ADATA,AREST
  17 7XDG          BNG   3  REPWD               [J IF WOT EXISTING   
  12 7XY6          LDX   0  A1(3)              [ 
  15 7YCQ          BZE   0  REPWD               [J IF EMPTY  
  10 7YXB          MHUNT    1,ADATA,ACONV
  17 7_C2          BNG   1  NOACV               [J IF NOT EXISTING   
   8 7_WL          STOZ     A1(1)
  10 82B=          NAMETOP  1,ADATA,AREST
  10 82TW    NOACV NAMETOP  3,ADATA,ACONV
  15 83*G          LDX   0  A1(3)               [N/W IN ACONV
   7 83T6          SBN   0  2
   7 84#Q          SLL   0  2
   9 84SB          LDCH  1  A1+1(3)  
   7 85#2          SRL   1  4
   8 85RL          BZE   1  OKC  
   7 86?=          SBN   0  4
   7 86QW          ADX   0  1
  16 87=G    OKC   STO   0  AWORK1(2)           [N/CH IN ACONV   
   8 87Q6          BRN      NEWCN
   7 889Q    REPWD LDN   5  0
   5 88PB    OLPREP  
  10 8992          LDX   1  APETADDR(2)  
  16 89NL          LDX   2  ACAP(2)             [PTR TO PERI CA  
   7 8=8=          ADN   2  1
  10 8=MW          FADDRESS 1,2,HLOCK1   
  15 8?7G          STO   5  0(2)                [REPLY WORD  
   6 8?M6          OLPEND
   9 8#6Q          BRN      K1TPOBJ  
   6 8#8F    WRONGLPCH   
   9 8#=8          LDX   3  ACAP(2)  
   7 8#?X          ADN   3  1
  13 8#*L          FADDRESS APETADDR(2),3,HLOCK1,2   
  21 8#C*          SBN   4  1                   [STORE UNEXPIRED CHARACTER COUNT IN  
  20 8#F4          STO   4  0(3)                [REPLY WORD OF OBJECT PROGRAM.   
   9 8#GR          LDN   3  FYINVCC  
   8 8#JG          BRN      XILL 
   4 8#LB    MOLE
   9 8*62          LDN   3  FYMODE   
   4 8*KL    XILL
  16 8B5=          CALL  7  TOPCA               [CHANGE TO PCA   
  17 8BJW          ACROSS   OLPODD,4            [FOR UNPLUG/ILLEGAL  
   4 8C4G    WC  
   9 8CJ6          LDN   3  FYCOUNT  
   8 8D3Q          BRN      XILL 
   4 8DHB    RESV
   9 8F32          LDN   3  FYNOBUF  
   8 8FGL          BRN      XILL 
   4 8G2=    OUTF
   8 8GFW          COMPQU   OUTF2
   9 8G_G          BRN      NEWCOMP  
   5 8HF6    OUTF1   
   8 8HYQ          LDX   0  GSIGN
   9 8JDB          ORS   0  AWORK4(2)
   5 8JY2    OUTF2   
   9 8KCL          LDX   0  ACA1(2)  
   7 8KX=          SRL   0  6
   8 8LBW          ANDN  0  #777 
   8 8LWG          SBN   0  #300 
  18 8MB6          BNZ   0  NMON                [J IF NOT ADD MODE #30000
   8 8MTQ          LDCT  5  #50  
   9 8N*B          BRN      OLPREP   
   5 8NT2    NEWCOMP 
   8 8P#L          LDCT  0  #200 
  17 8PS=          ERS   0  AWORK4(2)           [UNSET FNEARLY SWITCH
   9 8Q?W          BRN      K1TPOBJ  
   4 8QRG    NMON
   9 8R?6          LDN   3  FYOUTFULL
   8 8RQQ          BRN      OUTP 
   4 8S=B    OUTL
   9 8SQ2          LDN   3  FYOUTPUT 
   4 8T9L    OUTP
  16 8TP=          LDX   4  FTYPNO(2)           [FOR OUTPACKING  
   8 8W8W          BRN      XILL 
   4 8WNG    WAIT
   8 8X86          LDCT  0  #400 
  17 8XMQ          BXE   0  AWORK1(2),UP        [J IF LAST TRANSFER  
   5 8Y7B    NEARLY  
  15 8YM2          FDRMTEST APPWAIT,NODRM       [TOST IF DRM 
  15 8_6L          LDCT  5  #420                [REPLY WORD  
  10 8_L=          TESTREP2 APPWAIT,WAIT1
  17 925W          LDCT  5  #410                [REJECTED INOPERABLE 
   5 92KG    WAIT1   
  10 9356          LDX   1  APETADDR(2)  
  17 93JQ          BRN      OLPREP              [J TO SET REPLY WORD 
   5 944B    TOOMUCH 
  16 94J2          CALL  7  TOPCA               [CHANGE TO PCA   
   9 953L          ACROSS   OLPODD,2 
   5 95H=    NODRM   
  10 962W          TESTREP2 FILEFULL,OUTF
  16 96GG          CALL  7  TOPCA               [CHANGE TO PCA   
  21 9726          ACROSS   OLPODD,1            [LONGWAIT FOR BLOCK TO BE DESTROYED  
   5 97FQ    Z3TPOBJ 
   9 97_B          WHICHMOP TRANREST 
  17 98F2          BRN      UP                  [DO NOT APPEND IF MOP
   5 98YL    TRANREST
  10 99D=          HUNT  3,ADATA,ALINE   
  17 99XW          BNG   3  UP                  [J IF NO BUFFER BLOCK
  16 9=CG          LDX   0  A1(3)               [N/CH IN ALINE   
   7 9=X6          SBN   0  8
   8 9?BQ          BZE   0  UP   
   8 9?WB          LDCT  0  #400 
  21 9#B2          STO   0  AWORK1(2)           [AWRK1=#40000000 IF ENTRY FROM OFFREL
   8 9#TL          BRN   SETRT   
   5 9**=    UP    UP
   5 9*SW    TOPCA   
   8 9B#G          LDX   1  FX1  
   9 9BS6          TOPCA1   PLINK1(1)
   7 9C?Q          EXIT  7  0
   4 9CRB    #   
  10 9D?2          MENDAREA 200,K99TPOBJ 
   4 9DQL    #END
   8 ____ ...03052052000100000000