9 22*P ... SEG  IPBSCANB,,,,G170  
  16 22PD    # (C) COPYRIGHT INTERNATIONAL COMPUTERS LTD 1982.   
  13 22T* ...#     THIS EXCLUDES CODE UNDER #SKI G170
   8 22_=    #OPT  K0IPBSCANB=0  
  11 23DW    #LIS K0IPBSCANB>K0IPB>K0ALLGEO  
   7 23NN ...#OPT G170 = 0   
   6 23YG ...#SKI G170&1 
  15 248# ...# WITH UGUG EDIT M170 (CHANGE REMOTE *LP WIDTHS)
   4 24D6    [   
   4 24XQ    [   
   4 25CB    [   
  21 25X2    [                                  [PERFORMS SOME ACTIONS FOR WHICH...  
  20 26BL    [                                     THERE IS NO ROOM IN IPBSCAN   
   4 26W=    [   
   4 27*W    [   
  13 27TG          SEGENTRY K1IPBSCANB,SK1IPBSCANB   
  13 28*6          SEGENTRY K2IPBSCANB,SK2IPBSCANB   
  13 28MG          SEGENTRY K3IPBSCANB,SK3IPBSCANB   
   4 28SQ    [   
  16 28WN          FSHENTRY K4IPBSCANB,(GEOERR),(GEOERR),(GEOERR)
  16 28YL          FSHENTRY K5IPBSCANB,(GEOERR),(GEOERR),(GEOERR)
  16 292J          FSHENTRY K7IPBSCANB,(GEOERR),(GEOERR),(GEOERR)
  16 294G          FSHENTRY K8IPBSCANB,(GEOERR),(GEOERR),(GEOERR)
  16 296D          FSHENTRY K9IPBSCANB,(GEOERR),(GEOERR),(GEOERR)
  17 298B          FSHENTRY K10IPBSCANB,(GEOERR),(GEOERR),(GEOERR)   
   4 29=#    [   
   4 29#B    [   
   4 29S2    [   
  12 29TY          SEGENTRY  K11IPBSCANB,SK11IPB 
  21 29XW    [      ENTRY FOR SCANNING ACTIVITY AFTER CANCEL ATTACH CANCEL CONCEPTUAL
  18 29_S    [      CONCEPTUAL MODE #1000 OR SUP. SEG 'IDENTIFIER FREE7  
   4 2=3Q    [   
  12 2=5N          SEGENTRY  K12IPBSCANB,SK12IPB 
  14 2=7L    [  RETURN ENTRY AFTER GOING BACK TO IPBSCAN 
  10 2=9J    [   TO DO THE NEBUL ROUTINE 
  12 2===          SEGENTRY   K14IPBSCANB,SK14IPB
  13 2==Y    [      REPLACE CODE FOR IPBSCAN ENTRY K2
   9 2K3B    PAIR2 PAIR     IPBSCAN,3
   8 2KH2    #SKI  0?-PAIR2<2$2  
   4 2L2L    (   
   8 2LG=    #REP  0?-PAIR2$3-1  
   5 2L_W          +0
   4 2MFG    )   
   9 2M_6    PAIR3 PAIR     IPBSCAN,4
   4 2NDQ    #   
   9 2NYB    #DEF  ZLEN=PAIR3-PAIR2  
   4 2PD2    #   
   5 2PXL    XPAIR2  
   6 2QC=    #HAL  CPAT,0
   7 2QWW    XPLUS +CPATLEN  
   8 2RBG    #SKI  2<ZLEN$ZLEN   
   4 2RW6    (   
   6 2S*Q    #REP  ZLEN-2
   5 2STB          +0
   4 2T*2    )   
   5 2TSL    XPAIR3  
   8 2W#=    #HAL  CONSA+I7023,0 
   9 2WRW          +CONSALEN+I7023LEN
   4 2W_N    #   
   5 2X3L    PCLOSE  
  21 2X5J          0,#400:0,#01260000           [^CLOSE^ IDENTIFIER SUPERVISORY SEG  
  10 2X7G    #DEF  PCLOSELEN=0?-PCLOSE   
   4 2X?G    #   
   4 2XR6    #   
   4 2Y=Q    [   
   4 2YQB    [   
   4 2_=2    [   
   5 2_PL    SK11IPB 
   4 329=    [   
  16 32NW    [                                   TO SET UP A DCB 
   4 338G    [   
   7 33=P          LDN   4  1
   7 33#Y          LDN   7  0
   4 33C7    [   
   4 33FB    [   
   4 33HK    [   
  10 33KS    SK1IPBSCANB        [SETDB   
  14 33N6          SETNCORE ADCBULKLEN,2,AMXOR,ADCB,,1,2 
   8 33XY          BZE   7  SINIT
   5 347Q          UP
   5 3482    SINIT   
  19 348=          HUNTW    3,IDF,CONCEP        [PRESENT FOR CC CL OR RELPER 
  20 348G          BNG   3  SING                [ABSENT FOR DETACH OR OFF-TEST   
  10 348Q          LDX   4  ALOGLEN(3)   
   7 3492    SREP  ADX   3  4
   7 349=          SRL   4  1
  17 349G          LDX   6  A1-1(3)             [IDENTIFIER NUMBER   
  17 349Q          LDX   5  A1-2(3)             [AMOP/IPBIN ADDRESS  
   8 34=2    SING  LDX   1  FX2  
   9 34==          STO   5  AWORK1(1)
  20 34=G          STO   4  ICHARS(2)           [NO. OF IDENTIFIERS TO DEAL WITH 
   7 34=Q          SMO   5   
   8 34?2          LDX   0  CPPTR
  10 34?=          STO   5  AMOPADDR(1)  
  17 34?G          STO   0  CPPTR(1)            [DEVICE LIST POINTER 
  12 34?Q          HUNT2J   3,AMXOR,ADEVS,5,NYMOA
  11 34#2          SBX   6  A1+FOURTHWD(3)   
   7 34#=          LDX   0  6
  20 34#G          LDX   7  A1+FOURTHWD(3)      [LOWEST IDENT. NO. IN ADEVS BLOCK
   7 34#Q          SLL   0  2
  17 34*2          ADX   3  0                   [POINT TO ADEVS ENTRY
  10 34*=          LDX   5  A1+BPTR(3)   
  11 34*G          LDX   0  A1+FOURTHWD(3)   
  19 34*Q          BNZ   5  NYMO                [BUSY : 7023 BEFORE ONLINE   
   8 34B2          ANDX  0  BIT9 
  20 34B=          BNZ   0  NOPE                [CLOSED : DO FULL INITIALISATION 
  17 34BG          ADX   7  6                   [IDENTIFIER NUMBER   
  21 34BQ          DOWN     IPBINB,10           [AS IF INPUT RECEIVED FROM IDLE IDENT
   8 34C2          BRN      NYMO 
   4 34C=    #   
   8 34CG    NOPE  LDCT  0  #60  
  10 34CQ          STO   7  ACOMMUNE5(1) 
  11 34D2          LDX   7  A1+FOURTHWD(3)   
   7 34D=          ANDX  7  0
  21 34DG          BNZ   7  NYMO                [IDENTIFIER ALREADY BEING INITIALISED
   8 34DQ          LDCT  0  #20  
  18 34F2          ORS   0  A1+FOURTHWD(3)      [INDICATE INITIALISING   
  11 34F=          LDEX  0  A1+FOURTHWD(3)   
  15 34FG          BZE   0  UCONS               [MOP CONSOLE 
   7 34FQ          SBN   0  5
  15 34G2          BZE   0  U7023               [7023 CONSOLE
   7 34G=          SBN   0  5
  15 34GG          BZE   0  UCONS               [MOP DISPLAY 
   8 34H=          SBN   0  #20  
  15 34HG          BZE   0  UCONS               [PSEUDO VDU  
   8 34J2          ADN   3  A1   
  17 34J=          ACROSS     IPBSCAN,11    [INITIALISE BULK DEVICES 
  12 34JG    [  RETURN FROM IPBSCAN AFTER NEBUL  
   5 34JQ    SK12IPB 
  15 34K2          BRN      NYMO                [ANY MORE?   
   8 34K=    U7023 LDN   0  ZLEN 
   5 34KG    UCONS   
   7 34KQ          LDN   7  0
   7 34L?          LDX   3  0
   8 34LS          LDX   1  FX1  
   4 34MB    [   
   4 3572    [   
   4 35LL    [   
   8 35WD    [           NECON   
  20 366=    SK2IPBSCANB                         [GET ACT FOR MOP OR RJE CONSOLE 
   4 36KW    [   
   7 375G          ADX   1  3
   9 37K6          LDX   5  XPAIR2(1)
  17 384Q          GETACTX  5,XPLUS(1)          [CONSA/I7023 OR CPAT 
  20 38JB          LDX   0  ACOMMUNE5(2)        [LOWEST IDENTIFIER NUMBER ON IPB 
   8 3942          ADX   3  FX1  
   7 39HL          ADX   0  6
  18 3=3=          LDX   1  AMOPADDR(2)         [ADDRESS OF AMOP/IPBIN   
  18 3=GW          LDX   5  CPPTR(1)            [POINTER TO DEVICE LIST  
   9 3?2G          LDX   2  BPTR(2)  
   9 3?G6          STO   1  AWORK1(2)
  17 3?_Q          STO   0  ACC7(2)             [IDENTIFIER NUMBER.  
   9 3#FB          STO   5  CPPTR(2) 
  20 3#_2          LINKSET  2,PAIR2(3)          [STORE LINK TO K3 OR K4IPBSCAN   
   7 3*DL          LDX   3  6
   7 3*Y=          SLL   3  2
  18 3BCW          STO   3  ACC6(2)             [RELATIVE ADEVS POINTER  
  18 3BQ?          FPUT                    [START NEWLY CREATED ACTIVITY 
   8 3C4N          BZE   7  NYMO 
   5 3CC6          UP
  10 3CDC    NYMO  MHUNTW   2,AMXOR,ADCB 
   9 3CFN          LDX   4  ICHARS(2)
  21 3CG_          BCT   4  SNE                 [NOT FINISHED : GO ON TO NEXT DEVICE 
   5 3CJ=    NYMOA   
   7 3CLS          SUICIDE   
   7 3CQM    SNE   SLL   4  1
  10 3CRY          MHUNTW   3,IDF,CONCEP 
   8 3CT9          BRN      SREP 
   4 3CWQ    [   
   4 3CX_    [   
   4 3CYB    [   
   4 3CYR    [   
   6 3C_8    SK3IPBSCANB 
   4 3C_K    [   
  21 3D22    # K3IPBSCANB IS A SUBROUTINE FOR IPBSCAN TO INFORM THE CENTRAL OPERATOR 
  20 3D2C    # THAT ^THE WRONG TP FOR MOP USE IS LOADED^ AND TO SET UP A ^CLOSE^ 
  11 3D2S    # IDENTIFIER SUPERVISORY SEGMENT
   4 3D39    #   
  10 3D3L          MHUNTW   3,AMXOR,ADCB 
  21 3D43          LDX   7  IDENTNO(3)          [OBTAIN THE IDEN NO. FOR ^CLOSE^ SS  
  18 3D4D          SMO      IADIN(3)            [FIND THE OUTPUT ACTIVITY
   9 3D4T          LDX   3  IPBRING  
   9 3D5=          SBN   3  IPBRING  
  19 3D5M          LDCT  5  #40                 [CHECK IF OP ALREADY INFORMED
   9 3D64          ANDX  5  IPBSW(3) 
  17 3D6F          BNZ   5  SETUPCLOSE          [TRUE : SKIP INFORM  
  21 3D6W          LDCT  0  #40                 [SET ^REPORTED DCP WRONG FOR MOP USE^
  13 3D7?          ORS   0  IPBSW(3)            [FLAG
  10 3D7N          LGEOG    CPPTR(3),4   
  10 3D85          GEOPACK  4,4,UNITNO   
  10 3D8G          OUTPACK  4,1,GEOPER   
  21 3D8X          INFORM   1,IPBNOTW4,1        [THE WRONG TELEPROGRAM FOR MOP USE IS
  17 3D9#                                       [LOADED IN UNIT %A   
   6 3D9P    SETUPCLOSE  
  21 3D=6          SETNCORE PCLOSELEN,3,AMXOR,IOUT,1 [SET UP ^CLOSE^ IDENTIFIER SEG  
   9 3D=H          LDN   0  PCLOSE(1)
   9 3D=Y          LDN   1  IMOPTY(3)
   9 3D?*          MOVE  0  PCLOSELEN
   9 3D?Q          DSA   7  IPBIDE(3)
   5 3D#7          UP
   4 3D#J    [   
   4 4=B?    SUIC
   7 4=HF          SUICIDE   
   4 4=NP    [   
   5 4=NR    PRESET2 
   5 4=NT          0 
  19 4=NX          SEGENTRY K31IPBSCANB          [FOR USE BY MOPWIDTH MACRO  
   5 4=N_          0 
   6 4=P3    #FID  0,5,6 
   7 4=P5    #FID  15,23,72  
  19 4=P7          10,#76357632,#76207603,#76130000,0,8,#76672076,#27760177  
  18 4=P9          SEGENTRY K30IPBSCANB          [FOR USE BY AUTMOP MACRO
  10 4=P?          0,#76037673,#76737673 
   5 4=P*          0 
  10 4=PC    #DEF  P2MOPLEN=0?-PRESET2   
   4 4=PF    #   
   5 4=PH    PRESET2V
   5 4=PK          0 
   6 4=PM    #FID  0,5,2 
   7 4=PP    #FID  6,11,25   
   7 4=PR    #FID  15,23,80  
   8 4=PT          2,#76320000,0 
   6 4=P_    #FID  6,6,1 
  19 4=Q3          SEGENTRY K40IPBSCANB          [FOR USE BY VDUCODE MACRO   
   5 4=Q5          0 
   5 4=Q7          0 
  10 4=Q9          6,#14357613,#06200000 
  15 4=Q?          #40000014,#77763300,#76317420,#76067606   
   9 4=Q*    YCONTEXT       #20242   
   4 4=QC    #   
  21 4=QF    # ENTRY POINT TO CHECK THE IDF IF INPUT IS RECEIVED FROM AN IDLE IDENT. 
   4 4=QH    #   
   5 4=QK    SK14IPB 
  10 4=QM          MHUNTW   3,AMXOR,ADCB 
  17 4=QP          LDN   5  1                   [SET MOPOFF MARKER   
  17 4=QR          LDX   3  IADIN(3)            [AMOP/IPBIN ADDRESS  
   9 4=QT          STO   3  AWORK1(2)
  15 4=QX          LGEOG    CPPTR(3),4          [IPB GEOG NO.
  19 4=R3          IDFTPSCN XBI,SYSOF,CPPTR(3),7[CHECK IDENTIFIER IN THE IDF 
  18 4=R9          LDN   5  0                   [CLEAR TO SHOW MOPPED ON.
  20 4=R?    SYSOF HUNT2J   3,AMXOR,ADEVS,,SUIC [J TO SUICIDE IF BLK NOT FOUND   
  20 4=R*          ADX   3  6                   [POINTER TO CORRECT ADEVS ENTRY. 
   7 4=RC ...#UNS  CCERROR   
   4 4=RF ...(   
   8 4=RH ...      LDCT  0  #102 
  11 4=RK          ANDX  0  A1+FOURTHWD(3)   
   8 4=RM          BNZ   0  NOTON
  21 4=RP ...[                                   J IF MOP OFF OR WRONGED BIT SET IN A
   4 4=RR ...)   
  21 4=RT          BNZ   5  NOTON               [J. IF IDENTIFIER ALREADY MOPPED OFF.
  15 4=RX          LDX   6  ACOMMUNE2(2)        [IDF REPLY   
  11 4=R_          DEX   5  A1+FOURTHWD(3)   
   7 4=S7          LDX   0  6
  18 4=S?     ANDN 0 #6200 [ CLEAR SPOOLING,UNATTENDED AND 7502LP BITS   
   7 4=SH          ERS   0  6
  17 4=SM          ORS   6  A1+FOURTHWD(3)      [REMEMBER DEVICE TYPE
   7 4=SP          LDEX  5  6
   8 4=SR          ANDN  6  #400 
  15 4=ST          BNZ   6  NOTON               [TYPE UNKNOWN
  15 4=T3          LDX   6  0                   [ADCB FORMAT 
   7 4=T5          SRL   6  9
  10 4=T9          LDX   3  A1+FPTR(3)   
  16 4=T?          SBN   3  A1+FPTR             [POINT TO ADCB   
   9 4=T*          DOWN   IPBSCAN,8  
  10 4=TC          MHUNTW   3,AMXOR,ADCB 
  10 4=TF          LDX   7  IDENTNO(3)   
  17 4=TH          BZE   5  SCONS               [J. IF MOP CONSOLE   
   8 4=TK          SBN   5  10   
  17 4=TM          BZE   5  SDISP               [J. IF MOP DISPLAY   
   8 4=TP          ADN   5  10   
  15 4=TR          ALTLEND  3,ADCBULKLEN        [SHORTEN ADCB
  20 4=TX          LDCT  0  #24                 [UNSET THE ^SETTING UP^ MARKER   
  19 4=T_          STO   7  JSOURCE1(2)         [SET UP THE JOB SOURCE WORDS 
   8 4=W3          ORX   4  CACT 
  10 4=WR          STO   4  JSOURCE2(2)  
  10 4=WT          SMO      A1+FPTR(3)   
   9 4=WX          ANDX  0  FOURTHWD 
  10 4=W_          SMO      A1+FPTR(3)   
   9 4=X3          ERS   0  FOURTHWD 
  14 4=X9          ORS   6  IWAIT(3)            [B21,22  
  10 4=XC          LDX   0  ACOMMUNE2(2) 
  11 4=XF          SRL   0  ADCB7502LP&#37-16
   7 4=XH          ANDN  0  1
   7 4=XK          ORX   6  0
   9 4=XP          STO   6  IBULK(3) 
  18 4=XT          SMO      5                   [J. ON PERIPHERAL TYPE.  
   9 4=XX          BRN      TABL2-3  
   4 4=X_    #   
   8 4=Y3    TABL2 BRN      XLP  
   8 4=Y5          BRN      XCR  
  16 4=Y7          BRN      TMOF     [CLEAR RINGS THEN SUICIDE   
   8 4=Y9          BRN      XTR  
   8 4=Y?          BRN      XTP  
   4 4=Y*    #   
  18 4=YC    XCR   LDN   5  3                   [SET UP THE DEVICE TYPE. 
  10 4=YF          DCH   5  JSOURCE1(2)  
  17 4=YH          LDN   0  #4000               [TEST B12 OF FOURTHWD
  10 4=YK          SMO      A1+FPTR(3)   
   9 4=YM          ANDX  0  FOURTHWD 
  18 4=YP          BZE   0  XTR                 [ID NOT IN REMOTE MODE   
  21 4=YR          LDCT  0  3                   [REVISE MODE IN ADCB TO REMOTE MODE  
   9 4=YT          ERS   0  IMDNPU(3)
  21 4=YX    XTR   LDX   4  YCONTEXT(1)         [NO BREAK IN,REMOTE,READER,NO-USER   
   8 4=Y_          LDN   5  #61  
   8 4=_3          LDCT  0  #10  
  17 4=_5          STO   4  CONTEXT(2)          [SET THE CONTEXT MASK
  20 4=_7          ORS   0  IWAIT(3)            [INDICATE 'ONE SHOT INPUT' SENT  
  16 4=_9          STO   5  AMXMSK(2)           [AND REPORT MASK.
  17 4=_?          ACROSS   COMPROA,1            [GO AND READ INPUT. 
   4 4=_*    #   
   7 4=_C    XLP   LDN   4  2
   8 4=_F          BRN      XOUT 
   7 4=_H    XTP   LDN   4  1
  17 4=_K    XOUT  DCH   4  JSOURCE1(2)         [SET THE DEVICE TYPE.
  21 4=_M          LDX   5  ACOMMUNE4(2)        [CONSOLE PROPERTY NO. FROM IDFTPSCN. 
  19 4=_P          STO   5  JSOURCE3(2)         [AND THE CONSOLE PROPERTY NO.
   6 4=_Q ...#SKI G170&1 
  10 4=_R ...      DOWN     UMMENDS,13   
  21 4=_S ...      ACROSS   IPBLISTD,2          [GO TO OUTPUT HEADERS. (N.B. X5 > 0).
   4 4=_T    #   
  10 4=_X    SDISP LDN   4  PRESET2V(1)  
   8 4=__          BRN      SMOP 
  10 4?23    SCONS LDN   4  PRESET2+1(1) 
  19 4?25    SMOP  LDN   5  ICHARS(3)           [COMPLETE DCP INITIALISATION 
   9 4?27          LDX   0  IBIL(3)  
  10 4?29          MOVE  4  P2MOPLEN-1   
   9 4?2?          SMO      IADIN(3) 
   8 4?2*          LDX   4  CPPTR
  20 4?2C          STO   0  IBIL(3)             [PRESERVE IPBIN'S BREAK-IN LEVEL 
  19 4?2F          STO   4  CPPTR(2)            [POINTER TO IPB DEVICE LIST  
  10 4?2H          LDXC  0  ISTATUS(3)   
  16 4?2K          BCC      RCONS               [INITIALISE CPA  
  21 4?2M          LDX   0  BIT11               [IDLE IDENTIFIER BECAME UNAVAILABLE :
  21 4?2P          ORS   0  IWAIT(3)            [SET^INHIBIT INOPERABLE MESSAGE^ FLAG
  18 4?2R          BRN      RCONS               [J. TO INITIALISE CPA.   
   5 4?2T    RCONS   
  18 4?2X          ACROSS   IPBSCAN,12        [GO ACROSS TO RCONS ROUTINE
   4 4?2_    #   
  20 4?33    TMOF  LDX   3  A1+FPTR(3)          [ENTRY IF MOPOFF WHILE SETTING UP
   8 4?35          SBN   3  A1   
  18 4?37    NOTON SMO      A1+FPTR(3)          [CLEAR THE RING ELEMENTS.
   8 4?39          STOZ     BPTR 
  19 4?3?          LDCT  4  #24                 [UNSET THE SETTING UP BITS.  
  10 4?3*          STOZ     A1+BPTR(3)   
  11 4?3C          ANDX  4  A1+FOURTHWD(3)   
  11 4?3F          ERS   4  A1+FOURTHWD(3)   
  15 4?3H          BRN      SUIC                [CLEAR UP.   
  17 4?3M    XBI   GEOERR   1,BREAKIN!          [CANT HAVE BREAK-IN  
   4 4?8*    #END
   8 ____ ...17033071000500000000